Textverschlüsselung


Die Kryptologie oder Kryptographie beschäftigt sich vorwiegend mit dem Ver- und Entschlüsseln von Nachrichten und Botschaften. Dabei wird generell zwischen symmetrischen (ein- und derselbe Schlüssel bei Ver- und Entschlüsselung) und asymmetrischen Verfahren unterschieden.

Eines der einfachsten Verschlüsselungsverfahren erfolgt durch Buchstabenverschiebung und wird in der Kryptographie gerne als "Cäsar-Verschlüsselung" bezeichnet. Dabei entsteht aus einem Zeichensatz abcdefgh... durch Buchstabenverschiebung - in der einfachsten Variante um ein Zeichen nach rechts - der Zeichensatz bcdefghi...
Eine derart verschlüsselte Botschaft kann aufgrund der sichtbaren Wortlänge und der Häufigkeit einzelner Buchstaben (jedem Buchstaben des Klartextes wird stets der gleiche Buchstabe des verschlüsselten Textes zugeordnet) relativ leicht entschlüsselt werden.

Einen etwas besseren Schutz bietet die Kombination mehrerer Buchstabenverschiebungen. Dadurch wird zum einen nicht jedem Buchstaben des Klartextes der gleiche Buchstabe des verschlüsselten Textes zugeordnet und zum anderen die "wahre" Wortlänge verschleiert, da auch dem Leerzeichen - je nach Position innerhalb des Textes - verschiedene Zeichen zugeordnet werden.
Für eine derartige Buchstabenverschiebung müssen Auftraggeber und Auftragnehmer einen Zeichensatz, der z.B. aus Leerzeichen, numerischen Ziffern, Groß- und Kleinbuchstaben sowie Umlauten besteht, sowie ein Schlüsselwort vereinbaren.

Lautet dieses Schlüsselwort etwa nms, so werden insgesamt drei (= Anzahl der verschiedenen Buchstaben des Schlüsselwortes) verschiedene Buchstabenverschiebungen auf die Verschlüsselung des Klartextes angewendet. Die Position der einzelnen Zeichen n, m und s des dreibuchstabigen Schlüsselwortes nms im Zeichensatz erhält man über

=FINDEN(TEIL(Schluessel;{1;2;3};1);Zeichensatz),

wobei der verwendete Zeichensatz in einer Excel-Zelle mit dem Namen "Zeichensatz" und das Schlüsselwort in einer Excel-Zelle mit dem Namen "Schluessel" gespeichert ist.
Erhält man mit diesem Befehl z.B. das Array {54;53;59}, so bedeutet dies, dass das erste Zeichen n des Schlüsselwortes nms im aktuellen Zeichensatz an Position 54, das zweite Zeichen m an Position 53 und das dritte Zeichen s an Position 59 steht. Damit wird der vereinbarte Zeichensatz beim ersten Schlüsselzeichen um 54, beim zweiten Schlüsselzeichen um 53 und beim dritten Schlüsselzeichen um 59 Zeichen nach links verschoben.

Nun werden die drei "neuen" Zeichensätze abwechselnd auf die einzelnen Zeichen des Klartextes angewendet. Einem einzelnen Zeichen des Klartextes können daher bis zu drei (= Anzahl der verschiedenen Buchstaben des Schlüsselwortes) verschiedene Zeichen zugeordnet werden.

Um eine derartige Verschlüsselung mit dem TKP Excel durchzuführen, werden zuerst der Klartext in Zelle A2 (Bezeichnung "Klartext") und das Schlüsselwort in Zelle A5 (Bezeichnung "Schluessel") eingetragen.

Durch die Arrayformel

{=WENN(UND(ISTZAHL(FINDEN(TEIL(Schluessel;ZEILE(1:50);1);
Zeichensatz)));"";"un")&"gültig"} in Zelle B5

wird das bis zu 50 Zeichen lange Schlüsselwort
auf seine Gültigkeit bzgl. des vereinbarten Zeichensatzes überprüft.

In Spalte C werden die einzelnen Zeichen des Klartextes
mit Hilfe der Formel

=TEIL(Klartext;ZEILE();1)

aufgelistet, während in Spalte D die Position eines Klartextzeichens innerhalb des verwendeten Zeichensatzes mit Hilfe der Gleichung

=FINDEN(C1;Zeichensatz)

wiedergegeben wird.

Spalte E wiederholt dank der Formel

=TEIL(Schluessel;REST(ZEILE()-1;LÄNGE(Schluessel))+1;1)

die einzelnen Zeichen des Schlüsselwortes und legt somit fest, mit welchem Schlüssel (welcher Buchstabenverschiebung) das Klartextzeichen zu chiffrieren ist.

Spalte F ermittelt durch Eingabe der Formel

=FINDEN(E1;Zeichensatz)

die Position des Schlüsselwortzeichens innerhalb des Zeichensatzes und entscheidet somit über die anzuwendende Buchstabenverschiebung.

In Spalte G wird jedes einzelne Klartextzeichen in ein Chiffrezeichen übersetzt. Da die Funktion REST beim Modul m = Länge(Zeichensatz) alle ganzzahligen Werte des Intervalls [0; Länge(Zeichensatz)-1] liefert, die Positionen der Zeichen innerhalb des Zeichensatzes jedoch im Intervall [1; Länge(Zeichensatz)] liegen, gilt für die durchzuführende Buchstabenverschiebung:

=TEIL(Zeichensatz;REST(D1+F1-1;LÄNGE(Zeichensatz))+1;1).

Zum Schluss werden in Spalte H
die einzelnen Zeichen des verschlüsselten Textes über die Formeln

=G1 in Zelle H1

und

=WENN(ZEILE()>LÄNGE(Klartext);H2;H2&G3) ab Zelle H2

zusammengesetzt und der gesamte verschlüsselte Text
der letzten - nicht leeren - Zelle der Spalte H in Zelle A8 kopiert.

Formel 1

Um den verschlüsselten Text wieder in Klartext umzuwandeln, wird die Buchstabenverschiebung der Spalte G durch die Formel

=TEIL(Zeichensatz;REST(D1-F1-1;LÄNGE(Zeichensatz))+1;1)

rückgängig gemacht.

Formel 2